Merge branch feature-get-record into feature-partial-getlen
[~helmut/bidiragda.git] / Precond.agda
1 open import Relation.Binary.Core using (Decidable ; _≡_)
2
3 module Precond (Carrier : Set) (deq : Decidable {A = Carrier} _≡_) where
4
5 open import Data.Nat using (ℕ)
6 open import Data.Fin using (Fin ; zero ; suc)
7 open import Data.Fin.Props using (_≟_)
8 open import Data.List using (List ; [] ; _∷_)
9 open import Level using () renaming (zero to ℓ₀)
10 import Category.Monad
11 import Category.Functor
12 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′)
13 open Category.Monad.RawMonad {Level.zero} Data.Maybe.monad using (_>>=_)
14 open Category.Functor.RawFunctor {Level.zero} Data.Maybe.functor using (_<$>_)
15 open import Data.Vec using (Vec ; [] ; _∷_ ; map ; lookup ; toList ; tabulate)
16 open import Data.Vec.Properties using (map-cong ; map-∘ ; tabulate-∘)
17 import Data.List.All
18 open import Data.List.Any using (here ; there)
19 open Data.List.Any.Membership-≡ using (_∉_)
20 open import Data.Maybe using (just)
21 open import Data.Product using (∃ ; _,_ ; proj₂)
22 open import Function using (flip ; _∘_ ; id)
23 open import Function.Equality using (_⟶_ ; _⟨$⟩_)
24 open import Function.Injection using (module Injection) renaming (Injection to _↪_)
25 open Injection using (to)
26 open import Relation.Binary using (Setoid)
27 open import Relation.Binary.PropositionalEquality using (refl ; cong ; inspect ; [_] ; sym ; decSetoid) renaming (setoid to EqSetoid)
28 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
29 open import Relation.Nullary using (yes ; no)
30
31 open import Generic using (mapMV ; sequenceV ; sequence-map)
32 open import FinMap using (FinMapMaybe ; lookupM ; union ; fromFunc ; empty ; insert ; lemma-lookupM-empty ; delete-many ; lemma-tabulate-∘ ; delete ; lemma-lookupM-delete)
33 import CheckInsert
34 open CheckInsert (decSetoid deq) using (checkInsert ; lemma-checkInsert-new ; lemma-lookupM-checkInsert-other)
35 import BFF
36 open import Bidir (decSetoid deq) using (_in-domain-of_ ; lemma-assoc-domain ; lemma-just-sequence)
37 import GetTypes
38 open GetTypes.PartialVecVec using (Get ; module Get)
39 open BFF.PartialVecBFF (decSetoid deq) using (assoc ; enumerate ; denumerate ; bff)
40
41 lemma-lookup-map-just : {n : ℕ} (f : Fin n) {A : Set} (v : Vec A n) → lookup f (map Maybe.just v) ≡ Maybe.just (lookup f v)
42 lemma-lookup-map-just zero    (x ∷ xs) = refl
43 lemma-lookup-map-just (suc f) (x ∷ xs) = lemma-lookup-map-just f xs
44
45 lemma-maybe-just : {A : Set} → (a : A) → (ma : Maybe A) → maybe′ Maybe.just (just a) ma ≡ Maybe.just (maybe′ id a ma)
46 lemma-maybe-just a (just x) = refl
47 lemma-maybe-just a nothing = refl
48
49 lemma-union-delete-fromFunc : {m n : ℕ} {A : Set} {is : Vec (Fin n) m} {h : FinMapMaybe n A} {g : Vec A n} → (toList is) in-domain-of h → ∃ λ v → union h (delete-many is (map just g)) ≡ map just v
50 lemma-union-delete-fromFunc {is = []} {h = h} {g = g} p = _ , (begin
51   union h (map just g)
52     ≡⟨ lemma-tabulate-∘ (λ f → begin
53       maybe′ just (lookup f (map just g)) (lookup f h)
54         ≡⟨ cong (flip (maybe′ just) (lookup f h)) (lemma-lookup-map-just f g) ⟩
55       maybe′ just (just (lookup f g)) (lookup f h)
56         ≡⟨ lemma-maybe-just (lookup f g) (lookup f h) ⟩
57       just (maybe′ id (lookup f g) (lookup f h)) ∎) ⟩
58   tabulate (λ f → just (maybe′ id (lookup f g) (lookup f h)))
59     ≡⟨ tabulate-∘ just (λ f → maybe′ id (lookup f g) (lookup f h)) ⟩
60   map just (tabulate (λ f → maybe′ id (lookup f g) (lookup f h))) ∎)
61 lemma-union-delete-fromFunc {n = n} {is = i ∷ is} {h = h} {g = g} ((x , px) Data.List.All.∷ ps) = _ , (begin
62   union h (delete i (delete-many is (map just g)))
63     ≡⟨ lemma-tabulate-∘ inner ⟩
64   union h (delete-many is (map just g))
65     ≡⟨ proj₂ (lemma-union-delete-fromFunc ps) ⟩
66   map just _ ∎)
67   where inner : (f : Fin n) → maybe′ just (lookupM f (delete i (delete-many is (map just g)))) (lookup f h) ≡ maybe′ just (lookupM f (delete-many is (map just g))) (lookup f h)
68         inner f with f ≟ i
69         inner .i | yes refl = begin
70           maybe′ just (lookupM i (delete i (delete-many is (map just g)))) (lookup i h)
71             ≡⟨ cong (maybe′ just _) px ⟩
72           just x
73             ≡⟨ cong (maybe′ just _) (sym px) ⟩
74           maybe′ just (lookupM i (delete-many is (map just g))) (lookup i h) ∎
75         inner f | no f≢i = cong (flip (maybe′ just) (lookup f h)) (lemma-lookupM-delete (delete-many is (map just g)) f≢i)
76
77 assoc-enough : (G : Get) → {i : Setoid.Carrier (Get.I G)} → (s : Vec Carrier (to (Get.gl₁ G) ⟨$⟩ i)) → (v : Vec Carrier (Get.gl₂ G ⟨$⟩ i)) → ∃ (λ h → assoc (Get.get G (enumerate s)) v ≡ just h) → ∃ λ u → bff G s v ≡ just u
78 assoc-enough G s v (h , p) = let w , pw = lemma-union-delete-fromFunc (lemma-assoc-domain (get s′) v h p) in _ , (begin
79   bff G s v
80     ≡⟨ cong (flip _>>=_ (flip mapMV s′ ∘ flip lookupM) ∘ _<$>_ (flip union g′)) p ⟩
81   mapMV (flip lookupM (union h g′)) s′
82     ≡⟨ sym (sequence-map (flip lookupM (union h g′)) s′) ⟩
83   sequenceV (map (flip lookupM (union h g′)) s′)
84     ≡⟨ cong (sequenceV ∘ flip map s′ ∘ flip lookupM) pw ⟩
85   sequenceV (map (flip lookupM (map just w)) s′)
86     ≡⟨ cong sequenceV (map-cong (λ f → lemma-lookup-map-just f w) s′) ⟩
87   sequenceV (map (Maybe.just ∘ flip lookup w) s′)
88     ≡⟨ cong sequenceV (map-∘ just (flip lookup w) s′) ⟩
89   sequenceV (map Maybe.just (map (flip lookup w) s′))
90     ≡⟨ lemma-just-sequence (map (flip lookup w) s′) ⟩
91   just (map (flip lookup w) s′) ∎)
92   where open Get G
93         s′ = enumerate s
94         g  = fromFunc (denumerate s)
95         g′ = delete-many (get s′) g
96
97 data All-different {A : Set} : List A → Set where
98   different-[] : All-different []
99   different-∷  : {x : A} {xs : List A} → x ∉ xs → All-different xs → All-different (x ∷ xs)
100
101 lemma-∉-lookupM-assoc : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is xs ≡ just h → (i ∉ toList is) → lookupM i h ≡ nothing
102 lemma-∉-lookupM-assoc i []         []         .empty refl i∉is = lemma-lookupM-empty i
103 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h ph i∉is with assoc is' xs' | inspect (assoc is') xs'
104 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h () i∉is | nothing | [ ph' ]
105 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h ph i∉is | just h' | [ ph' ] = begin
106   lookupM i h
107     ≡⟨ sym (lemma-lookupM-checkInsert-other i i' (i∉is ∘ here) x' h' h ph) ⟩
108   lookupM i h'
109     ≡⟨ lemma-∉-lookupM-assoc i is' xs' h' ph' (i∉is ∘ there) ⟩
110   nothing ∎
111
112 different-assoc : {m n : ℕ} → (u : Vec (Fin n) m) → (v : Vec Carrier m) → All-different (toList u) → ∃ λ h → assoc u v ≡ just h
113 different-assoc []       []       p = empty , refl
114 different-assoc (u ∷ us) (v ∷ vs) (different-∷ u∉us diff-us) with different-assoc us vs diff-us
115 different-assoc (u ∷ us) (v ∷ vs) (different-∷ u∉us diff-us) | h , p' = insert u v h , (begin
116   assoc (u ∷ us) (v ∷ vs)
117     ≡⟨ refl ⟩
118   (assoc us vs >>= checkInsert u v)
119     ≡⟨ cong (flip _>>=_ (checkInsert u v)) p' ⟩
120   checkInsert u v h
121     ≡⟨ lemma-checkInsert-new u v h (lemma-∉-lookupM-assoc u us vs h p' u∉us) ⟩
122   just (insert u v h) ∎)