avoid useless repetition
[~helmut/bidiragda.git] / Precond.agda
1 open import Relation.Binary.Core using (Decidable ; _≡_)
2
3 module Precond (Carrier : Set) (deq : Decidable {A = Carrier} _≡_) where
4
5 open import Data.Nat using (ℕ)
6 open import Data.Fin using (Fin ; zero ; suc)
7 open import Data.Fin.Props using (_≟_)
8 open import Data.List using (List ; [] ; _∷_)
9 import Level
10 import Category.Monad
11 import Category.Functor
12 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′)
13 open Category.Monad.RawMonad {Level.zero} Data.Maybe.monad using (_>>=_)
14 open Category.Functor.RawFunctor {Level.zero} Data.Maybe.functor using (_<$>_)
15 open import Data.Vec using (Vec ; [] ; _∷_ ; map ; lookup ; toList ; tabulate)
16 open import Data.Vec.Properties using (map-cong ; map-∘ ; tabulate-∘)
17 import Data.List.All
18 open import Data.List.Any using (here ; there)
19 open Data.List.Any.Membership-≡ using (_∉_)
20 open import Data.Maybe using (just)
21 open import Data.Product using (∃ ; _,_ ; proj₁ ; proj₂)
22 open import Function using (flip ; _∘_ ; id)
23 open import Relation.Binary.PropositionalEquality using (refl ; cong ; inspect ; [_] ; sym ; decSetoid)
24 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
25 open import Relation.Nullary using (yes ; no)
26
27 open import Generic using (mapMV ; sequenceV ; sequence-map)
28 open import FinMap using (FinMapMaybe ; lookupM ; union ; fromFunc ; empty ; insert ; lemma-lookupM-empty ; delete-many ; lemma-tabulate-∘ ; delete ; lemma-lookupM-delete ; lemma-lookupM-fromFunc ; reshape ; lemma-reshape-id)
29 import CheckInsert
30 open CheckInsert (decSetoid deq) using (checkInsert ; lemma-checkInsert-new ; lemma-lookupM-checkInsert-other)
31 import BFF
32 import Bidir
33 open Bidir (decSetoid deq) using (_in-domain-of_ ; lemma-assoc-domain ; lemma-just-sequence)
34 import GetTypes
35 open GetTypes.VecVec using (Get ; module Get)
36 open BFF.VecBFF (decSetoid deq) using (assoc ; enumerate ; denumerate ; bff ; enumeratel)
37
38 lemma-maybe-just : {A : Set} → (a : A) → (ma : Maybe A) → maybe′ Maybe.just (just a) ma ≡ Maybe.just (maybe′ id a ma)
39 lemma-maybe-just a (just x) = refl
40 lemma-maybe-just a nothing = refl
41
42 lemma-union-delete-fromFunc : {m n : ℕ} {A : Set} {is : Vec (Fin n) m} {h : FinMapMaybe n A} {g : Fin n → A} → (toList is) in-domain-of h → ∃ λ v → union h (delete-many is (fromFunc g)) ≡ fromFunc v
43 lemma-union-delete-fromFunc {is = []} {h = h} {g = g} p = _ , (begin
44   union h (fromFunc g)
45     ≡⟨ lemma-tabulate-∘ (λ f → begin
46       maybe′ just (lookupM f (fromFunc g)) (lookupM f h)
47         ≡⟨ cong (flip (maybe′ just) (lookupM f h)) (lemma-lookupM-fromFunc g f) ⟩
48       maybe′ just (just (g f)) (lookupM f h)
49         ≡⟨ lemma-maybe-just (g f) (lookupM f h) ⟩
50       just (maybe′ id (g f) (lookupM f h)) ∎) ⟩
51   tabulate (λ f → just (maybe′ id (g f) (lookup f h)))
52     ≡⟨ tabulate-∘ just (λ f → maybe′ id (g f) (lookup f h)) ⟩
53   map just (tabulate (λ f → maybe′ id (g f) (lookup f h))) ∎)
54 lemma-union-delete-fromFunc {n = n} {is = i ∷ is} {h = h} {g = g} (Data.List.All._∷_ (x , px) ps) = _ , (begin
55   union h (delete i (delete-many is (fromFunc g)))
56     ≡⟨ lemma-tabulate-∘ inner ⟩
57   union h (delete-many is (fromFunc g))
58     ≡⟨ proj₂ (lemma-union-delete-fromFunc ps) ⟩
59   map just _ ∎)
60   where inner : (f : Fin n) → maybe′ just (lookupM f (delete i (delete-many is (fromFunc g)))) (lookup f h) ≡ maybe′ just (lookupM f (delete-many is (fromFunc g))) (lookup f h)
61         inner f with f ≟ i
62         inner .i | yes refl = begin
63           maybe′ just (lookupM i (delete i (delete-many is (fromFunc g)))) (lookup i h)
64             ≡⟨ cong (maybe′ just _) px ⟩
65           just x
66             ≡⟨ cong (maybe′ just _) (sym px) ⟩
67           maybe′ just (lookupM i (delete-many is (fromFunc g))) (lookup i h) ∎
68         inner f | no f≢i = cong (flip (maybe′ just) (lookup f h)) (lemma-lookupM-delete (delete-many is (fromFunc g)) f≢i)
69
70 assoc-enough : (G : Get) → {m : ℕ} → (s : Vec Carrier m) → (v : Vec Carrier (Get.getlen G m)) → ∃ (λ h → assoc (Get.get G (enumeratel m)) v ≡ just h) → ∃ λ u → bff G m s v ≡ just u
71 assoc-enough G {m} s v (h , p) = _ , (begin
72   bff G m s v
73     ≡⟨ cong (flip _>>=_ (flip mapMV t ∘ flip lookupM) ∘ _<$>_ (flip union (reshape g′ m))) p ⟩
74   mapMV (flip lookupM (union h (reshape g′ m))) t
75     ≡⟨ sym (sequence-map (flip lookupM (union h (reshape g′ m))) t) ⟩
76   sequenceV (map (flip lookupM (union h (reshape g′ m))) t)
77     ≡⟨ cong (sequenceV ∘ flip map t ∘ flip lookupM ∘ union h) (lemma-reshape-id g′) ⟩
78   sequenceV (map (flip lookupM (union h g′)) t)
79     ≡⟨ cong (sequenceV ∘ flip map t ∘ flip lookupM) (proj₂ wp) ⟩
80   sequenceV (map (flip lookupM (fromFunc (proj₁ wp))) t)
81     ≡⟨ cong sequenceV (map-cong (lemma-lookupM-fromFunc (proj₁ wp)) t) ⟩
82   sequenceV (map (Maybe.just ∘ proj₁ wp) t)
83     ≡⟨ cong sequenceV (map-∘ just (proj₁ wp) t) ⟩
84   sequenceV (map Maybe.just (map (proj₁ wp) t))
85     ≡⟨ lemma-just-sequence (map (proj₁ wp) t) ⟩
86   just (map (proj₁ wp) t) ∎)
87   where open Get G
88         s′ = enumerate s
89         g  = fromFunc (denumerate s)
90         g′ = delete-many (get s′) g
91         t  = enumeratel m
92         wp = lemma-union-delete-fromFunc (lemma-assoc-domain (get t) v h p)
93
94 data All-different {A : Set} : List A → Set where
95   different-[] : All-different []
96   different-∷  : {x : A} {xs : List A} → x ∉ xs → All-different xs → All-different (x ∷ xs)
97
98 lemma-∉-lookupM-assoc : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is xs ≡ just h → (i ∉ toList is) → lookupM i h ≡ nothing
99 lemma-∉-lookupM-assoc i []         []         .empty refl i∉is = lemma-lookupM-empty i
100 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h ph i∉is with assoc is' xs' | inspect (assoc is') xs'
101 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h () i∉is | nothing | [ ph' ]
102 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h ph i∉is | just h' | [ ph' ] = begin
103   lookupM i h
104     ≡⟨ sym (lemma-lookupM-checkInsert-other i i' (i∉is ∘ here) x' h' h ph) ⟩
105   lookupM i h'
106     ≡⟨ lemma-∉-lookupM-assoc i is' xs' h' ph' (i∉is ∘ there) ⟩
107   nothing ∎
108
109 different-assoc : {m n : ℕ} → (u : Vec (Fin n) m) → (v : Vec Carrier m) → All-different (toList u) → ∃ λ h → assoc u v ≡ just h
110 different-assoc []       []       p = empty , refl
111 different-assoc (u ∷ us) (v ∷ vs) (different-∷ u∉us diff-us) with different-assoc us vs diff-us
112 different-assoc (u ∷ us) (v ∷ vs) (different-∷ u∉us diff-us) | h , p' = insert u v h , (begin
113   assoc (u ∷ us) (v ∷ vs)
114     ≡⟨ refl ⟩
115   (assoc us vs >>= checkInsert u v)
116     ≡⟨ cong (flip _>>=_ (checkInsert u v)) p' ⟩
117   checkInsert u v h
118     ≡⟨ lemma-checkInsert-new u v h (lemma-∉-lookupM-assoc u us vs h p' u∉us) ⟩
119   just (insert u v h) ∎)