improve notation of theorem-1 using local bindings
[~helmut/bidiragda.git] / Precond.agda
1 open import Relation.Binary.Core using (Decidable ; _≡_)
2
3 module Precond (Carrier : Set) (deq : Decidable {A = Carrier} _≡_) where
4
5 open import Data.Nat using (ℕ)
6 open import Data.Fin using (Fin ; zero ; suc)
7 open import Data.Fin.Props using (_≟_)
8 open import Data.List using (List ; [] ; _∷_)
9 open import Level using () renaming (zero to ℓ₀)
10 import Category.Monad
11 import Category.Functor
12 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′)
13 open Category.Monad.RawMonad {Level.zero} Data.Maybe.monad using (_>>=_)
14 open Category.Functor.RawFunctor {Level.zero} Data.Maybe.functor using (_<$>_)
15 open import Data.Vec using (Vec ; [] ; _∷_ ; map ; lookup ; toList)
16 open import Data.Vec.Properties using (map-cong ; map-∘ ; tabulate-∘)
17 import Data.List.All
18 open import Data.List.Any using (here ; there)
19 open Data.List.Any.Membership-≡ using (_∉_)
20 open import Data.Maybe using (just)
21 open import Data.Product using (∃ ; _,_ ; proj₁ ; proj₂)
22 open import Function using (flip ; _∘_ ; id)
23 open import Relation.Binary using (Setoid)
24 open import Relation.Binary.PropositionalEquality using (refl ; cong ; inspect ; [_] ; sym ; decSetoid)
25 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
26 open import Relation.Nullary using (yes ; no)
27
28 open import FinMap using (FinMapMaybe ; lookupM ; union ; fromFunc ; empty ; insert ; lemma-lookupM-empty ; delete-many ; lemma-tabulate-∘ ; delete ; lemma-lookupM-delete ; lemma-lookupM-fromFunc ; reshape ; lemma-reshape-id)
29 import CheckInsert
30 open CheckInsert (decSetoid deq) using (checkInsert ; lemma-checkInsert-new ; lemma-lookupM-checkInsert-other)
31 import BFF
32 import Bidir
33 open Bidir (decSetoid deq) using (_in-domain-of_ ; lemma-assoc-domain)
34 import GetTypes
35 open GetTypes.PartialVecVec using (Get ; module Get)
36 open BFF.PartialVecBFF (decSetoid deq) using (assoc ; enumerate ; denumerate ; bff ; enumeratel)
37
38 lemma-maybe-just : {A : Set} → (a : A) → (ma : Maybe A) → maybe′ Maybe.just (just a) ma ≡ Maybe.just (maybe′ id a ma)
39 lemma-maybe-just a (just x) = refl
40 lemma-maybe-just a nothing = refl
41
42 lemma-union-delete-fromFunc : {m n : ℕ} {A : Set} {is : Vec (Fin n) m} {h : FinMapMaybe n A} {g : Fin n → A} → (toList is) in-domain-of h → ∃ λ v → union h (delete-many is (fromFunc g)) ≡ fromFunc v
43 lemma-union-delete-fromFunc {is = []} {h = h} {g = g} p = _ , (lemma-tabulate-∘ (λ f → begin
44       maybe′ just (lookupM f (fromFunc g)) (lookupM f h)
45         ≡⟨ cong (flip (maybe′ just) (lookupM f h)) (lemma-lookupM-fromFunc g f) ⟩
46       maybe′ just (just (g f)) (lookupM f h)
47         ≡⟨ lemma-maybe-just (g f) (lookupM f h) ⟩
48       just (maybe′ id (g f) (lookupM f h)) ∎))
49 lemma-union-delete-fromFunc {n = n} {is = i ∷ is} {h = h} {g = g} (Data.List.All._∷_ (x , px) ps) = _ , (begin
50   union h (delete i (delete-many is (fromFunc g)))
51     ≡⟨ lemma-tabulate-∘ inner ⟩
52   union h (delete-many is (fromFunc g))
53     ≡⟨ proj₂ (lemma-union-delete-fromFunc ps) ⟩
54   _ ∎)
55   where inner : (f : Fin n) → maybe′ just (lookupM f (delete i (delete-many is (fromFunc g)))) (lookup f h) ≡ maybe′ just (lookupM f (delete-many is (fromFunc g))) (lookup f h)
56         inner f with f ≟ i
57         inner .i | yes refl = begin
58           maybe′ just (lookupM i (delete i (delete-many is (fromFunc g)))) (lookup i h)
59             ≡⟨ cong (maybe′ just _) px ⟩
60           just x
61             ≡⟨ cong (maybe′ just _) (sym px) ⟩
62           maybe′ just (lookupM i (delete-many is (fromFunc g))) (lookup i h) ∎
63         inner f | no f≢i = cong (flip (maybe′ just) (lookup f h)) (lemma-lookupM-delete (delete-many is (fromFunc g)) f≢i)
64
65 assoc-enough : (G : Get) → {i : Get.|I| G} → (j : Get.|I| G) → (s : Vec Carrier (Get.|gl₁| G i)) → (v : Vec Carrier (Get.|gl₂| G j)) → ∃ (λ h → assoc (Get.get G (enumeratel (Get.|gl₁| G j))) v ≡ just h) → ∃ λ u → bff G j s v ≡ just u
66 assoc-enough G {i} j s v (h , p) = _ , cong (_<$>_ (flip map t ∘ flip lookupM) ∘ _<$>_ (flip union (reshape g′ (|gl₁| j)))) p
67   where open Get G
68         g′ = delete-many (get (enumerate s)) (fromFunc (denumerate s))
69         t  = enumeratel (|gl₁| j)
70
71 assoc-enough′ : (G : Get) → {i : Get.|I| G} → (s : Vec Carrier (Get.|gl₁| G i)) → (v : Vec Carrier (Get.|gl₂| G i)) → ∃ (λ h → assoc (Get.get G (enumeratel (Get.|gl₁| G i))) v ≡ just h) → ∃ λ u → bff G i s v ≡ just (map just u)
72 assoc-enough′ G {i} s v (h , p) = _ , (begin
73   bff G i s v
74     ≡⟨ proj₂ (assoc-enough G i s v (h , p)) ⟩
75   just (map (flip lookupM (union h (reshape g′ (|gl₁| i)))) t)
76     ≡⟨ cong just (begin _
77         ≡⟨ cong (flip map t ∘ flip lookupM ∘ union h) (lemma-reshape-id g′) ⟩
78       map (flip lookupM (union h g′)) t
79         ≡⟨ cong (flip map t ∘ flip lookupM) (proj₂ wp) ⟩
80       map (flip lookupM (fromFunc (proj₁ wp))) t
81         ≡⟨ map-cong (lemma-lookupM-fromFunc (proj₁ wp)) t ⟩
82       map (Maybe.just ∘ proj₁ wp) t
83         ≡⟨ map-∘ just (proj₁ wp) t ⟩
84       map Maybe.just (map (proj₁ wp) t) ∎) ⟩ _ ∎)
85   where open Get G
86         s′ = enumerate s
87         g  = fromFunc (denumerate s)
88         g′ = delete-many (get s′) g
89         t  = enumeratel (Get.|gl₁| G i)
90         wp = lemma-union-delete-fromFunc (lemma-assoc-domain (get t) v h p)
91
92 data All-different {A : Set} : List A → Set where
93   different-[] : All-different []
94   different-∷  : {x : A} {xs : List A} → x ∉ xs → All-different xs → All-different (x ∷ xs)
95
96 lemma-∉-lookupM-assoc : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is xs ≡ just h → (i ∉ toList is) → lookupM i h ≡ nothing
97 lemma-∉-lookupM-assoc i []         []         .empty refl i∉is = lemma-lookupM-empty i
98 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h ph i∉is with assoc is' xs' | inspect (assoc is') xs'
99 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h () i∉is | nothing | [ ph' ]
100 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h ph i∉is | just h' | [ ph' ] = begin
101   lookupM i h
102     ≡⟨ sym (lemma-lookupM-checkInsert-other i i' (i∉is ∘ here) x' h' h ph) ⟩
103   lookupM i h'
104     ≡⟨ lemma-∉-lookupM-assoc i is' xs' h' ph' (i∉is ∘ there) ⟩
105   nothing ∎
106
107 different-assoc : {m n : ℕ} → (u : Vec (Fin n) m) → (v : Vec Carrier m) → All-different (toList u) → ∃ λ h → assoc u v ≡ just h
108 different-assoc []       []       p = empty , refl
109 different-assoc (u ∷ us) (v ∷ vs) (different-∷ u∉us diff-us) with different-assoc us vs diff-us
110 different-assoc (u ∷ us) (v ∷ vs) (different-∷ u∉us diff-us) | h , p' = insert u v h , (begin
111   assoc (u ∷ us) (v ∷ vs)
112     ≡⟨ refl ⟩
113   (assoc us vs >>= checkInsert u v)
114     ≡⟨ cong (flip _>>=_ (checkInsert u v)) p' ⟩
115   checkInsert u v h
116     ≡⟨ lemma-checkInsert-new u v h (lemma-∉-lookupM-assoc u us vs h p' u∉us) ⟩
117   just (insert u v h) ∎)