cc81db4ad52d9bb2d1a30f04a0e824c752bd036b
[~helmut/bidiragda.git] / Precond.agda
1 open import Relation.Binary.Core using (Decidable ; _≡_)
2
3 module Precond (Carrier : Set) (deq : Decidable {A = Carrier} _≡_) where
4
5 open import Data.Nat using (ℕ)
6 open import Data.Fin using (Fin ; zero ; suc)
7 open import Data.Fin.Properties using (_≟_)
8 open import Data.List using (List ; [] ; _∷_)
9 open import Level using () renaming (zero to ℓ₀)
10 import Category.Monad
11 import Category.Functor
12 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′)
13 open Category.Monad.RawMonad {Level.zero} Data.Maybe.monad using (_>>=_)
14 open Category.Functor.RawFunctor {Level.zero} Data.Maybe.functor using (_<$>_)
15 open import Data.Vec using (Vec ; [] ; _∷_ ; map ; lookup ; toList)
16 open import Data.Vec.Properties using (map-cong ; map-∘ ; tabulate-∘)
17 import Data.List.All
18 open import Data.List.Any using (here ; there)
19 open import Data.List.Any.Membership.Propositional using (_∉_)
20 open import Data.Maybe using (just)
21 open import Data.Product using (∃ ; _,_ ; proj₁ ; proj₂)
22 open import Function using (flip ; _∘_ ; id)
23 open import Relation.Binary using (Setoid)
24 open import Relation.Binary.PropositionalEquality using (refl ; cong ; inspect ; [_] ; sym ; decSetoid)
25 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
26 open import Relation.Nullary using (yes ; no)
27
28 open import Structures using (IsFunctor ; module Shaped ; Shaped)
29 open import FinMap using (FinMapMaybe ; lookupM ; union ; fromFunc ; empty ; insert ; lemma-lookupM-empty ; delete-many ; lemma-tabulate-∘ ; delete ; lemma-lookupM-delete ; lemma-lookupM-fromFunc ; reshape ; lemma-reshape-id)
30 import CheckInsert
31 open CheckInsert (decSetoid deq) using (checkInsert ; lemma-checkInsert-new ; lemma-lookupM-checkInsert-other)
32 import BFF
33 import Bidir
34 open Bidir (decSetoid deq) using (_in-domain-of_ ; lemma-assoc-domain)
35 import GetTypes
36 open GetTypes.PartialShapeShape using (Get ; module Get)
37 open BFF.PartialShapeBFF (decSetoid deq) using (assoc ; enumerate ; denumerate ; bff)
38
39 lemma-maybe-just : {A : Set} → (a : A) → (ma : Maybe A) → maybe′ Maybe.just (just a) ma ≡ Maybe.just (maybe′ id a ma)
40 lemma-maybe-just a (just x) = refl
41 lemma-maybe-just a nothing = refl
42
43 lemma-union-delete-fromFunc : {m n : ℕ} {A : Set} {is : Vec (Fin n) m} {h : FinMapMaybe n A} {g : Fin n → A} → is in-domain-of h → ∃ λ v → union h (delete-many is (fromFunc g)) ≡ fromFunc v
44 lemma-union-delete-fromFunc {is = []} {h = h} {g = g} p = _ , (lemma-tabulate-∘ (λ f → begin
45       maybe′ just (lookupM f (fromFunc g)) (lookupM f h)
46         ≡⟨ cong (flip (maybe′ just) (lookupM f h)) (lemma-lookupM-fromFunc g f) ⟩
47       maybe′ just (just (g f)) (lookupM f h)
48         ≡⟨ lemma-maybe-just (g f) (lookupM f h) ⟩
49       just (maybe′ id (g f) (lookupM f h)) ∎))
50 lemma-union-delete-fromFunc {n = n} {is = i ∷ is} {h = h} {g = g} (Data.List.All._∷_ (x , px) ps) = _ , (begin
51   union h (delete i (delete-many is (fromFunc g)))
52     ≡⟨ lemma-tabulate-∘ inner ⟩
53   union h (delete-many is (fromFunc g))
54     ≡⟨ proj₂ (lemma-union-delete-fromFunc ps) ⟩
55   _ ∎)
56   where inner : (f : Fin n) → maybe′ just (lookupM f (delete i (delete-many is (fromFunc g)))) (lookup f h) ≡ maybe′ just (lookupM f (delete-many is (fromFunc g))) (lookup f h)
57         inner f with f ≟ i
58         inner .i | yes refl = begin
59           maybe′ just (lookupM i (delete i (delete-many is (fromFunc g)))) (lookup i h)
60             ≡⟨ cong (maybe′ just _) px ⟩
61           just x
62             ≡⟨ cong (maybe′ just _) (sym px) ⟩
63           maybe′ just (lookupM i (delete-many is (fromFunc g))) (lookup i h) ∎
64         inner f | no f≢i = cong (flip (maybe′ just) (lookup f h)) (lemma-lookupM-delete (delete-many is (fromFunc g)) f≢i)
65
66 module _ (G : Get) where
67   open Get G
68   open Shaped ViewShapeT using () renaming (content to contentV)
69
70   assoc-enough : {i : I} → (j : I) → (s : SourceContainer Carrier (gl₁ i)) → (v : ViewContainer Carrier (gl₂ j)) → ∃ (λ h → assoc (contentV (get (enumerate SourceShapeT (gl₁ j)))) (contentV v) ≡ just h) → ∃ λ u → bff G j s v ≡ just u
71   assoc-enough {i} j s v (h , p) = _ , cong (_<$>_ ((λ f → fmapS f t) ∘ flip lookupM) ∘ _<$>_ (flip union (reshape g′ (Shaped.arity SourceShapeT (gl₁ j))))) p
72     where g′ = delete-many (contentV (get (enumerate SourceShapeT (gl₁ i)))) (fromFunc (denumerate SourceShapeT s))
73           t  = enumerate SourceShapeT (gl₁ j)
74
75 module _ (G : Get) where
76   open Get G
77   open Shaped ViewShapeT using () renaming (content to contentV)
78
79   assoc-enough′ : {i : I} → (s : SourceContainer Carrier (gl₁ i)) → (v : ViewContainer Carrier (gl₂ i)) → ∃ (λ h → assoc (contentV (get (enumerate SourceShapeT (gl₁ i)))) (contentV v) ≡ just h) → ∃ λ u → bff G i s v ≡ just (fmapS just u)
80   assoc-enough′ {i} s v (h , p) = _ , (begin
81     bff G i s v
82       ≡⟨ proj₂ (assoc-enough G i s v (h , p)) ⟩
83     just (fmapS (flip lookupM (union h (reshape g′ (Shaped.arity SourceShapeT (gl₁ i))))) t)
84       ≡⟨ cong just (begin _
85           ≡⟨ cong ((λ f → fmapS f t) ∘ flip lookupM ∘ union h) (lemma-reshape-id g′) ⟩
86         fmapS (flip lookupM (union h g′)) t
87           ≡⟨ cong ((λ f → fmapS f t) ∘ flip lookupM) (proj₂ wp) ⟩
88         fmapS (flip lookupM (fromFunc (proj₁ wp))) t
89           ≡⟨ IsFunctor.cong (Shaped.isFunctor SourceShapeT (gl₁ i)) (lemma-lookupM-fromFunc (proj₁ wp)) t ⟩
90         fmapS (Maybe.just ∘ proj₁ wp) t
91           ≡⟨ IsFunctor.composition (Shaped.isFunctor SourceShapeT (gl₁ i)) just (proj₁ wp) t ⟩
92         fmapS Maybe.just (fmapS (proj₁ wp) t) ∎) ⟩ _ ∎)
93     where s′ = enumerate SourceShapeT (gl₁ i)
94           g  = fromFunc (denumerate SourceShapeT s)
95           g′ = delete-many (contentV (get s′)) g
96           t  = enumerate SourceShapeT (gl₁ i)
97           wp = lemma-union-delete-fromFunc (lemma-assoc-domain (contentV (get t)) (contentV v) p)
98
99 data All-different {A : Set} : List A → Set where
100   different-[] : All-different []
101   different-∷  : {x : A} {xs : List A} → x ∉ xs → All-different xs → All-different (x ∷ xs)
102
103 lemma-∉-lookupM-assoc : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → {h : FinMapMaybe n Carrier} → assoc is xs ≡ just h → (i ∉ toList is) → lookupM i h ≡ nothing
104 lemma-∉-lookupM-assoc i []         []         refl i∉is = lemma-lookupM-empty i
105 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') ph i∉is with assoc is' xs' | inspect (assoc is') xs'
106 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') () i∉is | nothing | [ ph' ]
107 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') {h} ph i∉is | just h' | [ ph' ] = begin
108   lookupM i h
109     ≡⟨ lemma-lookupM-checkInsert-other i i' (i∉is ∘ here) x' h' ph ⟩
110   lookupM i h'
111     ≡⟨ lemma-∉-lookupM-assoc i is' xs' ph' (i∉is ∘ there) ⟩
112   nothing ∎
113
114 different-assoc : {m n : ℕ} → (u : Vec (Fin n) m) → (v : Vec Carrier m) → All-different (toList u) → ∃ λ h → assoc u v ≡ just h
115 different-assoc []       []       p = empty , refl
116 different-assoc (u ∷ us) (v ∷ vs) (different-∷ u∉us diff-us) with different-assoc us vs diff-us
117 different-assoc (u ∷ us) (v ∷ vs) (different-∷ u∉us diff-us) | h , p' = insert u v h , (begin
118   assoc (u ∷ us) (v ∷ vs)
119     ≡⟨ refl ⟩
120   (assoc us vs >>= checkInsert u v)
121     ≡⟨ cong (flip _>>=_ (checkInsert u v)) p' ⟩
122   checkInsert u v h
123     ≡⟨ lemma-checkInsert-new u v h (lemma-∉-lookupM-assoc u us vs p' u∉us) ⟩
124   just (insert u v h) ∎)