Merge branch 'using-vec'
[~helmut/bidiragda.git] / Precond.agda
1 module Precond where
2
3 open import Data.Nat using (ℕ) renaming (zero to nzero ; suc to nsuc)
4 open import Data.Fin using (Fin ; zero ; suc)
5 open import Data.Vec using (Vec ; [] ; _∷_ ; map ; lookup ; toList)
6 open import Data.List.Any using (here ; there)
7 open Data.List.Any.Membership-≡ using (_∉_)
8 open import Data.Maybe using (just)
9 open import Data.Product using (∃ ; _,_)
10 open import Function using (flip ; _∘_)
11 open import Relation.Binary.Core using (_≡_ ; _≢_)
12 open import Relation.Binary.PropositionalEquality using (refl ; cong)
13 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
14
15 open import FinMap using (FinMap ; FinMapMaybe ; union ; fromFunc ; empty ; insert)
16 open import CheckInsert using (EqInst ; checkInsert ; lemma-checkInsert-new)
17 open import BFF using (fmap ; _>>=_)
18 open import Bidir using (lemma-∉-lookupM-assoc)
19
20 open BFF.VecBFF using (assoc ; enumerate ; denumerate ; bff)
21
22 assoc-enough : {getlen : ℕ → ℕ} (get : {A : Set} {n : ℕ} → Vec A n → Vec A (getlen n)) → {B : Set} {m : ℕ} → (eq : EqInst B) → (s : Vec B m) → (v : Vec B (getlen m)) → (h : FinMapMaybe m B) → assoc eq (get (enumerate s)) v ≡ just h → ∃ λ u → bff get eq s v ≡ just u
23 assoc-enough get {B} {m} eq s v h p = map (flip lookup (union h g)) s′ , (begin
24   bff get eq s v
25     ≡⟨ refl ⟩
26   fmap (flip map s′ ∘ flip lookup) (fmap (flip union g) (assoc eq (get s′) v))
27     ≡⟨ cong (fmap (flip map s′ ∘ flip lookup)) (cong (fmap (flip union g)) p) ⟩
28   fmap (flip map s′ ∘ flip lookup) (fmap (flip union g) (just h))
29     ≡⟨ refl ⟩
30   just (map (flip lookup (union h g)) s′) ∎)
31     where s′ : Vec (Fin m) m
32           s′ = enumerate s
33           g : FinMap m B
34           g = fromFunc (denumerate s)
35
36 all-different : {A : Set} {n : ℕ} → Vec A n → Set
37 all-different {_} {n} v = (i : Fin n) → (j : Fin n) → i ≢ j → lookup i v ≢ lookup j v
38
39 suc-≡ : {n : ℕ} {i j : Fin n} → (suc i ≡ suc j) → i ≡ j
40 suc-≡ refl = refl
41
42 different-swap : {A : Set} {n : ℕ} → (a b : A) → (v : Vec A n) → all-different (a ∷ b ∷ v) → all-different (b ∷ a ∷ v)
43 different-swap a b v p zero          zero          i≢j li≡lj = i≢j refl
44 different-swap a b v p zero          (suc zero)    i≢j li≡lj = p (suc zero) zero (λ ()) li≡lj
45 different-swap a b v p zero          (suc (suc j)) i≢j li≡lj = p (suc zero) (suc (suc j)) (λ ()) li≡lj
46 different-swap a b v p (suc zero)    zero          i≢j li≡lj = p zero (suc zero) (λ ()) li≡lj
47 different-swap a b v p (suc zero)    (suc zero)    i≢j li≡lj = i≢j refl
48 different-swap a b v p (suc zero)    (suc (suc j)) i≢j li≡lj = p zero (suc (suc j)) (λ ()) li≡lj
49 different-swap a b v p (suc (suc i)) zero          i≢j li≡lj = p (suc (suc i)) (suc zero) (λ ()) li≡lj
50 different-swap a b v p (suc (suc i)) (suc zero)    i≢j li≡lj = p (suc (suc i)) zero (λ ()) li≡lj
51 different-swap a b v p (suc (suc i)) (suc (suc j)) i≢j li≡lj = p (suc (suc i)) (suc (suc j)) i≢j li≡lj
52
53 different-drop : {A : Set} {n : ℕ} → (a : A) → (v : Vec A n) → all-different (a ∷ v) → all-different v
54 different-drop a v p i j i≢j = p (suc i) (suc j) (i≢j ∘ suc-≡)
55
56 different-∉ : {A : Set} {n : ℕ} → (x : A) (xs : Vec A n) → all-different (x ∷ xs) → x ∉ (toList xs)
57 different-∉ x [] p ()
58 different-∉ x (y ∷ ys) p (here px) = p zero (suc zero) (λ ()) px
59 different-∉ x (y ∷ ys) p (there pxs) = different-∉ x ys (different-drop y (x ∷ ys) (different-swap x y ys p)) pxs
60
61 different-assoc : {B : Set} {m n : ℕ} → (eq : EqInst B) → (u : Vec (Fin n) m) → (v : Vec B m) → all-different u → ∃ λ h → assoc eq u v ≡ just h
62 different-assoc eq []       []       p = empty , refl
63 different-assoc eq (u ∷ us) (v ∷ vs) p with different-assoc eq us vs (λ i j i≢j → p (suc i) (suc j) (i≢j ∘ suc-≡))
64 different-assoc eq (u ∷ us) (v ∷ vs) p | h , p' = insert u v h , (begin
65   assoc eq (u ∷ us) (v ∷ vs)
66     ≡⟨ refl ⟩
67   assoc eq us vs >>= checkInsert eq u v
68     ≡⟨ cong (flip _>>=_ (checkInsert eq u v)) p' ⟩
69   checkInsert eq u v h
70     ≡⟨ lemma-checkInsert-new eq u v h (lemma-∉-lookupM-assoc eq u us vs h p' (different-∉ u us p)) ⟩
71   just (insert u v h) ∎)