prove assoc-enough in the presence of delete
[~helmut/bidiragda.git] / Precond.agda
1 open import Relation.Binary.Core using (Decidable ; _≡_)
2
3 module Precond (Carrier : Set) (deq : Decidable {A = Carrier} _≡_) where
4
5 open import Data.Nat using (ℕ)
6 open import Data.Fin using (Fin ; zero ; suc)
7 open import Data.Fin.Props using (_≟_)
8 open import Data.List using (List ; [] ; _∷_)
9 import Level
10 import Category.Monad
11 import Category.Functor
12 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′)
13 open Category.Monad.RawMonad {Level.zero} Data.Maybe.monad using (_>>=_)
14 open Category.Functor.RawFunctor {Level.zero} Data.Maybe.functor using (_<$>_)
15 open import Data.Vec using (Vec ; [] ; _∷_ ; map ; lookup ; toList ; tabulate)
16 open import Data.Vec.Properties using (map-cong ; map-∘ ; tabulate-∘)
17 import Data.List.All
18 open import Data.List.Any using (here ; there)
19 open Data.List.Any.Membership-≡ using (_∉_)
20 open import Data.Maybe using (just)
21 open import Data.Product using (∃ ; _,_ ; proj₁ ; proj₂)
22 open import Function using (flip ; _∘_ ; id)
23 open import Relation.Binary.PropositionalEquality using (refl ; cong ; inspect ; [_] ; sym)
24 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
25 open import Relation.Nullary using (yes ; no)
26
27 open import Generic using (mapMV ; sequenceV ; sequence-map)
28 open import FinMap using (FinMapMaybe ; lookupM ; union ; fromFunc ; empty ; insert ; lemma-lookupM-empty ; delete-many ; lemma-tabulate-∘ ; delete ; lemma-lookupM-delete)
29 import CheckInsert
30 open CheckInsert Carrier deq using (checkInsert ; lemma-checkInsert-new ; lemma-lookupM-checkInsert-other)
31 import BFF
32 open import Bidir Carrier deq using (_in-domain-of_ ; lemma-assoc-domain ; lemma-just-sequence)
33
34 open BFF.VecBFF Carrier deq using (get-type ; assoc ; enumerate ; denumerate ; bff)
35
36 lemma-lookup-map-just : {n : ℕ} (f : Fin n) {A : Set} (v : Vec A n) → lookup f (map Maybe.just v) ≡ Maybe.just (lookup f v)
37 lemma-lookup-map-just zero    (x ∷ xs) = refl
38 lemma-lookup-map-just (suc f) (x ∷ xs) = lemma-lookup-map-just f xs
39
40 fromMaybe : {A : Set} → A → Maybe A → A
41 fromMaybe a ma = maybe′ id a ma
42
43 lemma-maybe-just : {A : Set} → (a : A) → (ma : Maybe A) → maybe′ Maybe.just (just a) ma ≡ Maybe.just (maybe′ id a ma)
44 lemma-maybe-just a (just x) = refl
45 lemma-maybe-just a nothing = refl
46
47 lemma-union-delete-fromFunc : {m n : ℕ} {A : Set} {is : Vec (Fin n) m} {h : FinMapMaybe n A} {g : Vec A n} → (toList is) in-domain-of h → ∃ λ v → union h (delete-many is (map just g)) ≡ map just v
48 lemma-union-delete-fromFunc {is = []} {h = h} {g = g} p = _ , (begin
49   union h (map just g)
50     ≡⟨ lemma-tabulate-∘ (λ f → begin
51       maybe′ just (lookup f (map just g)) (lookup f h)
52         ≡⟨ cong (flip (maybe′ just) (lookup f h)) (lemma-lookup-map-just f g) ⟩
53       maybe′ just (just (lookup f g)) (lookup f h)
54         ≡⟨ lemma-maybe-just (lookup f g) (lookup f h) ⟩
55       just (fromMaybe (lookup f g) (lookup f h)) ∎) ⟩
56   tabulate (λ f → just (fromMaybe (lookup f g) (lookup f h)))
57     ≡⟨ tabulate-∘ just (λ f → fromMaybe (lookup f g) (lookup f h)) ⟩
58   map just (tabulate (λ f → fromMaybe (lookup f g) (lookup f h))) ∎)
59 lemma-union-delete-fromFunc {n = n} {is = i ∷ is} {h = h} {g = g} (p Data.List.All.∷ ps) = _ , (begin
60   union h (delete i (delete-many is (map just g)))
61     ≡⟨ lemma-tabulate-∘ (λ f → (begin
62       maybe′ just (lookupM f (delete i (delete-many is (map just g)))) (lookup f h)
63         ≡⟨ inner f ⟩
64       maybe′ just (lookupM f (delete-many is (map just g))) (lookup f h) ∎)) ⟩
65   union h (delete-many is (map just g))
66     ≡⟨ proj₂ (lemma-union-delete-fromFunc ps) ⟩
67   map just _ ∎)
68   where inner : (f : Fin n) → maybe′ just (lookupM f (delete i (delete-many is (map just g)))) (lookup f h) ≡ maybe′ just (lookupM f (delete-many is (map just g))) (lookup f h)
69         inner f with f ≟ i
70         inner .i | yes refl = begin
71           maybe′ just (lookupM i (delete i (delete-many is (map just g)))) (lookup i h)
72             ≡⟨ cong (maybe′ just _) (proj₂ p) ⟩
73           just (proj₁ p)
74             ≡⟨ cong (maybe′ just _) (sym (proj₂ p)) ⟩
75           maybe′ just (lookupM i (delete-many is (map just g))) (lookup i h) ∎
76         inner f | no f≢i = cong (flip (maybe′ just) (lookup f h)) (lemma-lookupM-delete (delete-many is (map just g)) f≢i)
77
78 assoc-enough : {getlen : ℕ → ℕ} (get : get-type getlen) → {m : ℕ} → (s : Vec Carrier m) → (v : Vec Carrier (getlen m)) → ∃ (λ h → assoc (get (enumerate s)) v ≡ just h) → ∃ λ u → bff get s v ≡ just u
79 assoc-enough get s v (h , p) = let w , pw = lemma-union-delete-fromFunc (lemma-assoc-domain (get s′) v h p) in _ , (begin
80   bff get s v
81     ≡⟨ cong (flip _>>=_ (flip mapMV s′ ∘ flip lookupM) ∘ _<$>_ (flip union g′)) p ⟩
82   mapMV (flip lookupM (union h g′)) s′
83     ≡⟨ sym (sequence-map (flip lookupM (union h g′)) s′) ⟩
84   sequenceV (map (flip lookupM (union h g′)) s′)
85     ≡⟨ cong (sequenceV ∘ flip map s′ ∘ flip lookupM) pw ⟩
86   sequenceV (map (flip lookupM (map just w)) s′)
87     ≡⟨ cong sequenceV (map-cong (λ f → lemma-lookup-map-just f w) s′) ⟩
88   sequenceV (map (Maybe.just ∘ flip lookup w) s′)
89     ≡⟨ cong sequenceV (map-∘ just (flip lookup w) s′) ⟩
90   sequenceV (map Maybe.just (map (flip lookup w) s′))
91     ≡⟨ lemma-just-sequence (map (flip lookup w) s′) ⟩
92   just (map (flip lookup w) s′) ∎)
93   where s′ = enumerate s
94         g  = fromFunc (denumerate s)
95         g′ = delete-many (get s′) g
96
97 data All-different {A : Set} : List A → Set where
98   different-[] : All-different []
99   different-∷  : {x : A} {xs : List A} → x ∉ xs → All-different xs → All-different (x ∷ xs)
100
101 lemma-∉-lookupM-assoc : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is xs ≡ just h → (i ∉ toList is) → lookupM i h ≡ nothing
102 lemma-∉-lookupM-assoc i []         []         .empty refl i∉is = lemma-lookupM-empty i
103 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h ph i∉is with assoc is' xs' | inspect (assoc is') xs'
104 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h () i∉is | nothing | [ ph' ]
105 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h ph i∉is | just h' | [ ph' ] = begin
106   lookupM i h
107     ≡⟨ sym (lemma-lookupM-checkInsert-other i i' (i∉is ∘ here) x' h' h ph) ⟩
108   lookupM i h'
109     ≡⟨ lemma-∉-lookupM-assoc i is' xs' h' ph' (i∉is ∘ there) ⟩
110   nothing ∎
111
112 different-assoc : {m n : ℕ} → (u : Vec (Fin n) m) → (v : Vec Carrier m) → All-different (toList u) → ∃ λ h → assoc u v ≡ just h
113 different-assoc []       []       p = empty , refl
114 different-assoc (u ∷ us) (v ∷ vs) (different-∷ u∉us diff-us) with different-assoc us vs diff-us
115 different-assoc (u ∷ us) (v ∷ vs) (different-∷ u∉us diff-us) | h , p' = insert u v h , (begin
116   assoc (u ∷ us) (v ∷ vs)
117     ≡⟨ refl ⟩
118   (assoc us vs >>= checkInsert u v)
119     ≡⟨ cong (flip _>>=_ (checkInsert u v)) p' ⟩
120   checkInsert u v h
121     ≡⟨ lemma-checkInsert-new u v h (lemma-∉-lookupM-assoc u us vs h p' u∉us) ⟩
122   just (insert u v h) ∎)