use different formulation of all-different
[~helmut/bidiragda.git] / Precond.agda
1 open import Relation.Binary.Core using (Decidable ; _≡_)
2
3 module Precond (Carrier : Set) (deq : Decidable {A = Carrier} _≡_) where
4
5 open import Data.Nat using (ℕ) renaming (zero to nzero ; suc to nsuc)
6 open import Data.Fin using (Fin ; zero ; suc)
7 open import Data.Vec using (Vec ; [] ; _∷_ ; map ; lookup ; toList)
8 open import Data.List.Any using (here ; there)
9 open Data.List.Any.Membership-≡ using (_∉_)
10 open import Data.Maybe using (just)
11 open import Data.Product using (∃ ; _,_)
12 open import Function using (flip ; _∘_)
13 open import Relation.Binary.Core using (_≢_)
14 open import Relation.Binary.PropositionalEquality using (refl ; cong)
15 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
16
17 open import FinMap using (FinMap ; FinMapMaybe ; union ; fromFunc ; empty ; insert)
18 import CheckInsert
19 open CheckInsert Carrier deq using (checkInsert ; lemma-checkInsert-new)
20 open import BFF using (fmap ; _>>=_)
21 import Bidir
22 open Bidir Carrier deq using (lemma-∉-lookupM-assoc)
23
24 open BFF.VecBFF Carrier deq using (get-type ; assoc ; enumerate ; denumerate ; bff)
25
26 assoc-enough : {getlen : ℕ → ℕ} (get : get-type getlen) → {m : ℕ} → (s : Vec Carrier m) → (v : Vec Carrier (getlen m)) → ∃ (λ h → assoc (get (enumerate s)) v ≡ just h) → ∃ λ u → bff get s v ≡ just u
27 assoc-enough get s v (h , p) = u , cong (fmap (flip map s′ ∘ flip lookup) ∘ (fmap (flip union g))) p
28     where s′ = enumerate s
29           g  = fromFunc (denumerate s)
30           u  = map (flip lookup (union h g)) s′
31
32 data All-different {A : Set} : {n : ℕ} → Vec A n → Set where
33   different-[] : All-different []
34   different-∷  : {n : ℕ} {x : A} {xs : Vec A n} → x ∉ toList xs → All-different xs → All-different (x ∷ xs)
35
36 different-assoc : {m n : ℕ} → (u : Vec (Fin n) m) → (v : Vec Carrier m) → All-different u → ∃ λ h → assoc u v ≡ just h
37 different-assoc []       []       p = empty , refl
38 different-assoc (u ∷ us) (v ∷ vs) (different-∷ u∉us diff-us) with different-assoc us vs diff-us
39 different-assoc (u ∷ us) (v ∷ vs) (different-∷ u∉us diff-us) | h , p' = insert u v h , (begin
40   assoc (u ∷ us) (v ∷ vs)
41     ≡⟨ refl ⟩
42   assoc us vs >>= checkInsert u v
43     ≡⟨ cong (flip _>>=_ (checkInsert u v)) p' ⟩
44   checkInsert u v h
45     ≡⟨ lemma-checkInsert-new u v h (lemma-∉-lookupM-assoc u us vs h p' u∉us) ⟩
46   just (insert u v h) ∎)