Merge branch 'modparam'
[~helmut/bidiragda.git] / Precond.agda
1 open import Relation.Binary.Core using (Decidable ; _≡_)
2
3 module Precond (Carrier : Set) (deq : Decidable {A = Carrier} _≡_) where
4
5 open import Data.Nat using (ℕ) renaming (zero to nzero ; suc to nsuc)
6 open import Data.Fin using (Fin ; zero ; suc)
7 open import Data.Vec using (Vec ; [] ; _∷_ ; map ; lookup ; toList)
8 open import Data.List.Any using (here ; there)
9 open Data.List.Any.Membership-≡ using (_∉_)
10 open import Data.Maybe using (just)
11 open import Data.Product using (∃ ; _,_)
12 open import Function using (flip ; _∘_)
13 open import Relation.Binary.Core using (_≢_)
14 open import Relation.Binary.PropositionalEquality using (refl ; cong)
15 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
16
17 open import FinMap using (FinMap ; FinMapMaybe ; union ; fromFunc ; empty ; insert)
18 import CheckInsert
19 open CheckInsert Carrier deq using (checkInsert ; lemma-checkInsert-new)
20 open import BFF using (fmap ; _>>=_)
21 import Bidir
22 open Bidir Carrier deq using (lemma-∉-lookupM-assoc)
23
24 open BFF.VecBFF Carrier deq using (get-type ; assoc ; enumerate ; denumerate ; bff)
25
26 assoc-enough : {getlen : ℕ → ℕ} (get : get-type getlen) → {m : ℕ} → (s : Vec Carrier m) → (v : Vec Carrier (getlen m)) → (h : FinMapMaybe m Carrier) → assoc (get (enumerate s)) v ≡ just h → ∃ λ u → bff get s v ≡ just u
27 assoc-enough get {m} s v h p = map (flip lookup (union h g)) s′ , (begin
28   bff get s v
29     ≡⟨ refl ⟩
30   fmap (flip map s′ ∘ flip lookup) (fmap (flip union g) (assoc (get s′) v))
31     ≡⟨ cong (fmap (flip map s′ ∘ flip lookup)) (cong (fmap (flip union g)) p) ⟩
32   fmap (flip map s′ ∘ flip lookup) (fmap (flip union g) (just h))
33     ≡⟨ refl ⟩
34   just (map (flip lookup (union h g)) s′) ∎)
35     where s′ : Vec (Fin m) m
36           s′ = enumerate s
37           g : FinMap m Carrier
38           g = fromFunc (denumerate s)
39
40 all-different : {A : Set} {n : ℕ} → Vec A n → Set
41 all-different {_} {n} v = (i : Fin n) → (j : Fin n) → i ≢ j → lookup i v ≢ lookup j v
42
43 suc-injective : {n : ℕ} {i j : Fin n} → (suc i ≡ suc j) → i ≡ j
44 suc-injective refl = refl
45
46 different-swap : {A : Set} {n : ℕ} → (a b : A) → (v : Vec A n) → all-different (a ∷ b ∷ v) → all-different (b ∷ a ∷ v)
47 different-swap a b v p zero          zero          i≢j li≡lj = i≢j refl
48 different-swap a b v p zero          (suc zero)    i≢j li≡lj = p (suc zero) zero (λ ()) li≡lj
49 different-swap a b v p zero          (suc (suc j)) i≢j li≡lj = p (suc zero) (suc (suc j)) (λ ()) li≡lj
50 different-swap a b v p (suc zero)    zero          i≢j li≡lj = p zero (suc zero) (λ ()) li≡lj
51 different-swap a b v p (suc zero)    (suc zero)    i≢j li≡lj = i≢j refl
52 different-swap a b v p (suc zero)    (suc (suc j)) i≢j li≡lj = p zero (suc (suc j)) (λ ()) li≡lj
53 different-swap a b v p (suc (suc i)) zero          i≢j li≡lj = p (suc (suc i)) (suc zero) (λ ()) li≡lj
54 different-swap a b v p (suc (suc i)) (suc zero)    i≢j li≡lj = p (suc (suc i)) zero (λ ()) li≡lj
55 different-swap a b v p (suc (suc i)) (suc (suc j)) i≢j li≡lj = p (suc (suc i)) (suc (suc j)) i≢j li≡lj
56
57 different-drop : {A : Set} {n : ℕ} → (a : A) → (v : Vec A n) → all-different (a ∷ v) → all-different v
58 different-drop a v p i j i≢j = p (suc i) (suc j) (i≢j ∘ suc-injective)
59
60 different-∉ : {A : Set} {n : ℕ} → (x : A) (xs : Vec A n) → all-different (x ∷ xs) → x ∉ (toList xs)
61 different-∉ x [] p ()
62 different-∉ x (y ∷ ys) p (here px) = p zero (suc zero) (λ ()) px
63 different-∉ x (y ∷ ys) p (there pxs) = different-∉ x ys (different-drop y (x ∷ ys) (different-swap x y ys p)) pxs
64
65 different-assoc : {m n : ℕ} → (u : Vec (Fin n) m) → (v : Vec Carrier m) → all-different u → ∃ λ h → assoc u v ≡ just h
66 different-assoc []       []       p = empty , refl
67 different-assoc (u ∷ us) (v ∷ vs) p with different-assoc us vs (λ i j i≢j → p (suc i) (suc j) (i≢j ∘ suc-injective))
68 different-assoc (u ∷ us) (v ∷ vs) p | h , p' = insert u v h , (begin
69   assoc (u ∷ us) (v ∷ vs)
70     ≡⟨ refl ⟩
71   assoc us vs >>= checkInsert u v
72     ≡⟨ cong (flip _>>=_ (checkInsert u v)) p' ⟩
73   checkInsert u v h
74     ≡⟨ lemma-checkInsert-new u v h (lemma-∉-lookupM-assoc u us vs h p' (different-∉ u us p)) ⟩
75   just (insert u v h) ∎)